flake.nix

{
  description = "horizon-nix-gen";
  inputs = {
    cabal2nix = {
      url = "github:NixOS/cabal2nix";
      flake = false;
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
    };
    horizon-platform = {
      url = "git+https://gitlab.homotopic.tech/horizon/horizon-platform";
    };
    lint-utils = {
      url = "git+https://gitlab.homotopic.tech/nix/lint-utils";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
  };
  outputs =
    inputs@
    { self
    , flake-utils
    , horizon-platform
    , lint-utils
    , nixpkgs
    , ...
    }:
    flake-utils.lib.eachSystem [ "x86_64-linux" ] (system:
    let
      pkgs = import nixpkgs { inherit system; };
      hsPkgs = pkgs.haskell.packages.ghc942.override {
        overrides = hfinal: hprev:
          with pkgs.haskell.lib;
          horizon-platform.packages.${system} //
          {
            horizon-gen-nix = hfinal.callCabal2nix "horizon-gen-nix" ./. { };
          };
      };
      horizon-gen-nix-bin = pkgs.writers.writeBashBin "horizon-gen-nix" ''
        export PATH=${pkgs.nix-prefetch-git}:$PATH
        ${hsPkgs.horizon-gen-nix}/bin/horizon-gen-nix
      '';
    in
    {
      apps.default = {
        type = "app";
        program = "${horizon-gen-nix-bin}/bin/horizon-gen-nix";
      };
      devShells.default = hsPkgs.horizon-gen-nix.env.overrideAttrs (attrs: {
        buildInputs = attrs.buildInputs ++ [
          hsPkgs.cabal-install
          pkgs.nixpkgs-fmt
        ];
      });
      packages.default = hsPkgs.horizon-gen-nix;
      checks =
        {
          hlint = lint-utils.outputs.linters.${system}.hlint self;
          hpack = lint-utils.outputs.linters.${system}.hpack self;
          nixpkgs-fmt = lint-utils.outputs.linters.${system}.nixpkgs-fmt self;
          stylish-haskell = lint-utils.outputs.linters.${system}.stylish-haskell self;
        };
    });
}